Criteria

Wat een criterium is

Een criterium is de voorwaarde waaraan een cel moet voldoen voordat een functie hem meetelt, optelt of meeneemt in een gemiddelde. Het is de tweede helft van een paar: een bereik om naar te kijken en een criterium waaraan elke cel in dat bereik wordt getoetst.

AANTAL.ALS neemt één paar, AANTALLEN.ALS maximaal 127. SOM.ALS, GEMIDDELDE.ALS, SOMMEN.ALS, GEMIDDELDEN.ALS, MAX.ALS.VOORWAARDEN en MIN.ALS.VOORWAARDEN voegen daar het bereik met de getallen aan toe.

Let op de volgorde van de argumenten:

• SOM.ALS en GEMIDDELDE.ALS: eerst het bereik dat wordt getoetst, dan het criterium en dan de getallen (die je mag weglaten als het getoetste bereik zelf de getallen bevat)
• SOMMEN.ALS, GEMIDDELDEN.ALS, MAX.ALS.VOORWAARDEN en MIN.ALS.VOORWAARDEN: eerst de getallen, daarna de paren

Een criterium is een waarde, geen formule: het is een getal, een stukje tekst, of een tekst die met een vergelijkingsoperator begint.

De vormen van een criterium

Welke cellen voldoen, hangt af van hoe het criterium is geschreven. Zonder operator moet de cel gelijk zijn aan het criterium. Met een vergelijkingsoperator ervoor vergelijkt Excel elke cel met het deel achter de operator. De tabel toont de vormen die je bij een controle nodig hebt; een patroon met * of ? staat uitgelegd op de pagina over jokertekens.

=AANTAL.ALS(B2:B100, ">1000")

=AANTAL.ALS(B2:B100; ">1000")

=AANTALLEN.ALS(C2:C100, "MEM", D2:D100, "")

=AANTALLEN.ALS(C2:C100; "MEM"; D2:D100; "")

=AANTAL.ALS(D2:D100, "<>")

=AANTAL.ALS(D2:D100; "<>")

Aanhalingstekens en de ampersand

Een vergelijkingsoperator hoort bij het criterium en staat dus tussen aanhalingstekens: ">". Een celverwijzing is geen tekst en staat dus buiten de aanhalingstekens, vastgeplakt aan de operator met &.

Excel plakt beide aan elkaar en leest het resultaat als één criterium. Met het getal 5000 in E1 wordt ">" & E1 de tekst >5000.

Dezelfde regel geldt voor elke operator en voor functies: ">=" & DATUM(2025; 12; 15) plakt de operator aan een datum die DATUM berekent. Een criterium dat al compleet is, zoals >1000 getypt in een cel, gebruik je met de verwijzing alleen: AANTAL.ALS(B2:B100; E1).

=AANTAL.ALS(B2:B100, ">" & E1)

=AANTAL.ALS(B2:B100; ">" & E1)

=AANTAL.ALS(B2:B100, ">E1")

=AANTAL.ALS(B2:B100; ">E1")

=AANTAL.ALS(A2:A100, "<>" & E1)

=AANTAL.ALS(A2:A100; "<>" & E1)

Datums in een criterium

Excel slaat een datum op als serieel getal, dus een datumcriterium is een getalcriterium: ">=" & G1 plakt de operator aan het seriële getal achter de datum in G1. Voor een periode heb je twee criteria op dezelfde datumkolom nodig, een voor het begin (>=) en een voor het einde (<=). Zowel de eerste als de laatste dag telt mee, en dat is bij een afgrenzingstest meestal wat je wilt.

Typ de datum niet als tekst. Een criterium als ">=15-12-2025" wordt omgezet met de regio-instelling van de computer, dus hetzelfde bestand kan op de laptop van een collega een ander resultaat geven. Een datumcel of DATUM(2025; 12; 15) is daar niet van afhankelijk.

Bevatten de datums ook een tijdstip (een boeking op 31 december 2025 om 14:30), dan mist het criterium "<=" & 31 december 2025 die boeking, omdat dat moment later is dan middernacht. Gebruik dan "<" & (einddatum + 1).

=AANTALLEN.ALS(B2:B100, ">=" & G1, B2:B100, "<=" & G2)

=AANTALLEN.ALS(B2:B100; ">=" & G1; B2:B100; "<=" & G2)

=AANTALLEN.ALS(B2:B100, ">=" & G1, B2:B100, "<" & G2 + 1)

=AANTALLEN.ALS(B2:B100; ">=" & G1; B2:B100; "<" & G2 + 1)

Hoofdletters, kleine letters en getallen als tekst

Criteria maken geen verschil tussen hoofdletters en kleine letters: mem, MEM en Mem vinden dezelfde cellen. Er is geen schakelaar om dat te veranderen. Als het verschil ertoe doet, heb je SOMPRODUCT met GELIJK nodig in plaats van een criterium.

Getallen die als tekst zijn opgeslagen (een groen driehoekje in de hoek, vaak na een export) gedragen zich per soort criterium anders:

• een exact criterium als 5000 vindt zowel het getal 5000 als de tekst 5000
• een vergelijking als ">1000" kijkt alleen naar echte getallen, dus een tekst 5000 wordt niet meegeteld
• in het bereik dat SOMMEN.ALS optelt, wordt tekst genegeerd, dus een kolom met bedragen als tekst geeft een totaal van 0

Zet de kolom eerst om, bijvoorbeeld door in een hulpkolom met 1 te vermenigvuldigen of met Tekst naar kolommen.

Meerdere voorwaarden: EN en OF

Paren in AANTALLEN.ALS, SOMMEN.ALS, GEMIDDELDEN.ALS, MAX.ALS.VOORWAARDEN en MIN.ALS.VOORWAARDEN worden altijd met EN gecombineerd: een rij telt alleen mee als aan elk paar is voldaan.

Voor OF op één kolom tel je twee functies op: AANTALLEN.ALS(C2:C100; "MEM") + AANTALLEN.ALS(C2:C100; "BNK"). Zijn er meer dan twee opties, zet ze dan in een matrixconstante en zet SOM eromheen: SOM(AANTALLEN.ALS(C2:C100; {"MEM"\"BNK"})). AANTALLEN.ALS geeft dan een telling per optie en SOM telt ze op.

Dit is OF op één kolom. De opties moeten elkaar uitsluiten, zoals twee verschillende dagboekcodes. Kan een rij aan beide opties voldoen, dan wordt de rij twee keer geteld.

Voor OF over verschillende kolommen (dagboek is MEM, of het bedrag is hoger dan 10.000) tel je de twee aantallen op en trek je het aantal rijen af dat aan beide voldoet, of gebruik je SOMPRODUCT.

Bereiken die even groot moeten zijn

In AANTALLEN.ALS, SOMMEN.ALS, GEMIDDELDEN.ALS, MAX.ALS.VOORWAARDEN en MIN.ALS.VOORWAARDEN moet elk bereik evenveel rijen en kolommen hebben, anders geeft Excel #WAARDE!. B2:B100 met C2:C101 is al te veel.

SOM.ALS en GEMIDDELDE.ALS zijn minder streng en daardoor gevaarlijker: ze gebruiken de cel linksboven van het op te tellen bereik en nemen de vorm van het getoetste bereik over, dus een bereik dat een rij te laag begint geeft geen foutmelding maar telt de verkeerde rijen op.

Zet de bereiken vast met absolute verwijzingen ($B$2:$B$100) als je de formule kopieert, en geef alle bereiken dezelfde eerste en laatste rij. Een benoemd bereik of een tabelkolom houdt ze vanzelf gelijk.

Verwante onderwerpen

• JokertekensJokertekens zijn tekens die voor andere tekens staan, zodat een criterium of zoekwaarde een deel van een tekst kan vinden in plaats van de hele tekst.
• OperatorenOperatoren zijn de symbolen in een formule waarmee je rekent, vergelijkt, tekst samenvoegt of verwijzingen combineert. Excel past ze in een vaste volgorde toe, wat veel ogenschijnlijk foute uitkomsten verklaart.
• Serieel getal: datums en tijdenExcel slaat een datum op als aantal dagen en een tijd als deel van een dag, zodat je ze kunt aftrekken, optellen en vergelijken. Leer dagen tellen, tekstdatums herstellen en uren optellen.
• Celverwijzingen: relatief, absoluut en gemengdEen celverwijzing is het adres dat een formule leest. Dollartekens bepalen of het adres meeschuift als je de formule kopieert, en dat goed doen laat een formule een hele kolom of tabel vullen.